43.5 Функции и переменные для статистических графиков

Функция: histogram (list)

Функция: histogram (list, option_1, option_2, ...)

Функция: histogram (one_column_matrix)

Функция: histogram (one_column_matrix, option_1, option_2, ...)

Функция: histogram (one_row_matrix)

Функция: histogram (one_row_matrix, option_1, option_2, ...)

Эта функция строит гистограмму для непрерывной выборки. Данные выборки должны быть представлены в виде списка или одномерной матрицы.

Доступны следующие опции:

• Опции, определенные в пакете draw. См. также bars и barsplot.
• nclasses - число классов в гистограмме (10 по умолчанию).

См. также discrete_freq и continuous_freq для подсчета данных, и bars и barsplot для построения гистограмм непрерывных данных.

Примеры:

Простая гистограмма с восемью классами.

(%i1) load ("descriptive")$
(%i2) s1 : read_list (file_search ("pidigits.data"))$
(%i3) histogram (
        s1,
        nclasses     = 8,
        title        = "pi digits",
        xlabel       = "digits",
        ylabel       = "Absolute frequency",
        fill_color   = grey,
        fill_density = 0.6)$

Функция: scatterplot (list)

Функция: scatterplot (list, option_1, option_2, ...)

Функция: scatterplot (matrix)

Функция: scatterplot (matrix, option_1, option_2, ...)

Строит корреляционную диаграмму (scatter diagrams) для одномерной (list) или многомерной (matrix) выборки.

Доступны следующие опции:

• Опции, определенные в пакете draw.
• nclasses - число классов в гистограмме (10 по умолчанию).

Примеры:

Одномерная корреляционная диаграмма для гауссовой выборки.

(%i1) load ("descriptive")$
(%i2) load ("distrib")$
(%i3) scatterplot(
        random_normal(0,1,200),
        xaxis      = true,
        point_size = 2,
        terminal   = eps,
        eps_width  = 10,
        eps_height = 2)$

Двумерная корреляционная диаграмма.

(%i1) load ("descriptive")$
(%i2) s2 : read_matrix (file_search ("wind.data"))$
(%i3) scatterplot(
        submatrix(s2, 1,2,3),
        title      = "Data from stations #4 and #5",
        point_type = diamant,
        point_size = 2,
        color      = blue)$

Трехмерная корреляционная диаграмма.

(%i1) load ("descriptive")$
(%i2) s2 : read_matrix (file_search ("wind.data"))$
(%i3) scatterplot(submatrix (s2, 1,2))$

Пятимерная корреляционная диаграмма, с гистограммой, содержащей пать классов.

(%i1) load ("descriptive")$
(%i2) s2 : read_matrix (file_search ("wind.data"))$
(%i3) scatterplot(
        s2,
        nclasses     = 5,
        fill_color   = blue,
        fill_density = 0.3,
        xtics        = 5)$

По поводу построения точек в двух или трех измерениях, соединенных линиями, см. points. См. bars по поводу опций, управляющих выводом гистограмм.

См. также histogram.

Функция: barsplot (list)

Функция: barsplot (list, option_1, option_2, ...)

Функция: barsplot (one_column_matrix)

Функция: barsplot (one_column_matrix, option_1, option_2, ...)

Функция: barsplot (one_row_matrix)

Функция: barsplot (one_row_matrix, option_1, option_2, ...)

Аналогична histogram но для дискретных, численных или категоризированных, статистических переменных.

Доступны следующие опции:

• Опции, определенные в пакете draw.
• box_width – относительная ширина прямоугольников (3/4 по умолчанию). Это число должно быть в интервале [0,1].

Пример:

(%i1) load ("descriptive")$
(%i2) s3 : read_matrix (file_search ("biomed.data"))$
(%i3) barsplot(col(s3,2),
         title        = "Ages",
         xlabel       = "years",
         box_width    = 1/2,
         fill_density = 0.3)$

По поводу опций, управляющих выводом диаграмм, см. bars пакета draw. См. также функции histogram и piechart.

Функция: piechart (list)

Функция: piechart (list, option_1, option_2, ...)

Функция: piechart (one_column_matrix)

Функция: piechart (one_column_matrix, option_1, option_2, ...)

Функция: piechart (one_row_matrix)

Функция: piechart (one_row_matrix, option_1, option_2, ...)

Аналогична barsplot, но вместо прямоугольников строит сектора, т.е. круговую диаграмму.

Доступны следующие опции:

• Опции, определенные в пакете draw.
• pie_center – центр диаграммы ([0,0] по умолчанию).
• pie_radius – радиус диаграммы (1 по умолчанию).

Пример:

(%i1) load ("descriptive")$
(%i2) s1 : read_list (file_search ("pidigits.data"))$
(%i3) piechart(
        s1,
        xrange      = [-1.1, 1.3],
        yrange      = [-1.1, 1.1],
        axis_top    = false,
        axis_right  = false,
        axis_left   = false,
        axis_bottom = false,
        xtics       = none,
        ytics       = none,
        title       = "Digit frequencies in pi")$

См. также barsplot.

Функция: boxplot (data)

Функция: boxplot (data, option_1, option_2, ...)

Эта функция строит диаграмму типа "ящик-с-усами" (box-and-whishker). Аргумент data может быть списком, что не представляет большого интереса, т.к. подобные диаграммы в основном используются для сравнения различных выборок или матриц, чтобы сравнить две или более компонент многомерной выборки. Но data также может быть списком выборок, возможно различной длины (это единственная функция в пакете descriptive, которая допускает такой тип данных).

Доступны следующие опции:

• Опции, определенные в пакете draw.
• box_width - относительная ширина ящиков (3/4 по умолчанию). Это число должно быть в интервале [0,1].

Примеры:

Диаграмма "ящик-с-усами" для многомерной выборки.

(%i1) load ("descriptive")$
(%i2) s2 : read_matrix(file_search("wind.data"))$
(%i3) boxplot(s2,
        box_width  = 0.2,
        title      = "Windspeed in knots",
        xlabel     = "Stations",
        color      = red,
        line_width = 2) $

Диаграмма "ящик-с-усами" для трех выборок различной длины.

(%i1) load ("descriptive")$
(%i2) A :
       [[6, 4, 6, 2, 4, 8, 6, 4, 6, 4, 3, 2],
        [8, 10, 7, 9, 12, 8, 10],
        [16, 13, 17, 12, 11, 18, 13, 18, 14, 12]]$
(%i3) boxplot (A)$