Previous: Funciones y variables de parámetros descriptivos, Subir: descriptive [Índice general][Índice]
Dibuja diagramas de barras para variables estadísticas discretas, tanto para una como para más muestras.
data puede ser una lista de resultados provenientes de una muestra o una matriz de m filas y n columnas, representando n muestras de tamaño m cada una.
Las opciones disponibles son:
3/4): ancho relativo de los rectángulos. Este
valor debe pertenecer al rango [0,1].
clustered): indica cómo se agrupan las
diferentes muestras. Son valores válidos: clustered y stacked.
1): un número positivo que representa
la separación entre dos grupos consecutivos de barras.
[]): una lista de colores para múltiples
muestras. Cuando el número de muestras sea mayor que el de colores especificados,
los colores adicionales necesarios se seleccionan aleatoriamente. Véase color para más
información.
absolute): indica la escala de las ordenadas.
Valores admitidos son: absolute, relative y and percent.
orderlessp): los valores admitidos para esta
opción son: orderlessp y ordergreatp, indicando cómo se deben ordenar
los resultados muestrales sobre el eje-x.
[]): es una lista de cadenas de
texto a usar como leyendas. Cuando la lista tenga una longitud diferente de cero o
del número de muestras, se devolverá un mensaje de error.
0): indica a qué altura comienza
a dibujarse el gráfico de barra sobre el eje de abscisas.
draw, excepto xtics, que se asigna
internamente por barsplot. Si es necesario que el usuario le dé su propio
valor a esta opción, o quiere construir una escena más compleja,
debe hacer uso de barsplot_description. Véase el ejemplo más abajo.
draw: key, color,
fill_color, fill_density y line_width. Véase también
bars.
La función barsplot_description crea un objeto gráfico
útil para formar escenas complejas, junto con otros objetos gráficos.
Se dispone también de la función wxbarsplot para crear
histogramas incorporados en los interfaces wxMaxima y iMaxima.
Ejemplos:
Muestra univariante en formato matricial. Frecuencias absolutas.
(%i1) load ("descriptive")$
(%i2) m : read_matrix (file_search ("biomed.data"))$
(%i3) barsplot(
col(m,2),
title = "Ages",
xlabel = "years",
box_width = 1/2,
fill_density = 3/4)$
Dos muestras de diferente tamaño, con frecuencias relativas y colores definidos por el usuario.
(%i1) load ("descriptive")$
(%i2) l1:makelist(random(10),k,1,50)$
(%i3) l2:makelist(random(10),k,1,100)$
(%i4) barsplot(
l1,l2,
box_width = 1,
fill_density = 1,
bars_colors = [black, grey],
frequency = relative,
sample_keys = ["A", "B"])$
Cuatro muestras no numéricas de igual tamaño.
(%i1) load ("descriptive")$
(%i2) barsplot(
makelist([Yes, No, Maybe][random(3)+1],k,1,50),
makelist([Yes, No, Maybe][random(3)+1],k,1,50),
makelist([Yes, No, Maybe][random(3)+1],k,1,50),
makelist([Yes, No, Maybe][random(3)+1],k,1,50),
title = "Asking for something to four groups",
ylabel = "# of individuals",
groups_gap = 3,
fill_density = 0.5,
ordering = ordergreatp)$
Barras apiladas verticalmente.
(%i1) load ("descriptive")$
(%i2) barsplot(
makelist([Yes, No, Maybe][random(3)+1],k,1,50),
makelist([Yes, No, Maybe][random(3)+1],k,1,50),
makelist([Yes, No, Maybe][random(3)+1],k,1,50),
makelist([Yes, No, Maybe][random(3)+1],k,1,50),
title = "Asking for something to four groups",
ylabel = "# of individuals",
grouping = stacked,
fill_density = 0.5,
ordering = ordergreatp)$
barsplot en un contexto multiplot.
(%i1) load ("descriptive")$
(%i2) l1:makelist(random(10),k,1,50)$
(%i3) l2:makelist(random(10),k,1,100)$
(%i4) bp1 :
barsplot_description(
l1,
box_width = 1,
fill_density = 0.5,
bars_colors = [blue],
frequency = relative)$
(%i5) bp2 :
barsplot_description(
l2,
box_width = 1,
fill_density = 0.5,
bars_colors = [red],
frequency = relative)$
(%i6) draw(gr2d(bp1), gr2d(bp2))$
Para las opciones relacionadas con los diagramas de barras, véase bars
del paquete draw.
Véanse también las funciones histogram y piechart.
Dibuja diagramas de cajas (box-and-whishker). El argumento data puede
ser una lista, lo cual no es de gran interés, puesto que estos gráficos
se utilizan principalmente para comparar distintas muestras, o una matriz,
de manera que sea posible comparar dos o más componentes de una muestra
multivariante. También se permite que data sea una lista de muestras
con posibles tamaños diferentes; de hecho, esta es la única función
del paquete descriptive que admite esta estructura de datos.
La caja se dibuja desde el primer cuartil hasta el tercero, con un segmento
horizontal situado a la altura del segundo cuartil o mediana. Por defecto,
los bigotes inferior y superior se sitúan a la altura de los valores mínimo
y máximo, respectivamente. La opción range se puede utilizar para indicar
que los valores mayores que
quantile(x,3/4)+range*(quantile(x,3/4)-quantile(x,1/4)),
o menores que
quantile(x,1/4)-range*(quantile(x,3/4)-quantile(x,1/4)),
deben considerarse atípicos, en cuyo caso se dibujan como puntos aislados, al
tiempo que los bigotes se colocan en los extremos del resto de la muestra.
Opciones disponibles:
3/4): ancho relativo de las cajas.
This value must be in the range [0,1].
vertical): valores posibles: vertical
y horizontal.
inf): coeficiente positivo del rango intercuartílico para
declarar los límites de los datos atípicos.
1): tamaño de los círculos para los datos atípicos.
draw, excepto points_joined,
point_size, point_type, xtics, ytics, xrange
y yrange, que se asignan internamente por boxplot. Si es necesario
que el usuario le dé sus propios valores a estas opciones, o quiere construir
una escena más compleja, debe hacer uso de boxplot_description.
draw: key, color,
y line_width.
La función boxplot_description crea un objeto gráfico
útil para formar escenas complejas, junto con otros objetos gráficos.
Se dispone también de la función wxboxplot para crear
histogramas incorporados en los interfaces wxMaxima y iMaxima.
Ejemplos:
Diagrama de cajas de una muestra multivariante.
(%i1) load ("descriptive")$
(%i2) s2 : read_matrix(file_search("wind.data"))$
(%i3) boxplot(s2,
box_width = 0.2,
title = "Windspeed in knots",
xlabel = "Stations",
color = red,
line_width = 2)$
Diagrama de cajas de tres muestras de tamaños diferentes.
(%i1) load ("descriptive")$
(%i2) A :
[[6, 4, 6, 2, 4, 8, 6, 4, 6, 4, 3, 2],
[8, 10, 7, 9, 12, 8, 10],
[16, 13, 17, 12, 11, 18, 13, 18, 14, 12]]$
(%i3) boxplot (A, box_orientation = horizontal)$
La opción range puede utilizarse para tratar con datos atípicos.
(%i1) load ("descriptive")$
(%i2) B: [[7, 15, 5, 8, 6, 5, 7, 3, 1],
[10, 8, 12, 8, 11, 9, 20],
[23, 17, 19, 7, 22, 19]] $
(%i3) boxplot (B, range=1)$ (%i4) boxplot (B, range=1.5, box_orientation = horizontal)$
(%i5) draw2d(
boxplot_description(
B,
range = 1.5,
line_width = 3,
outliers_size = 2,
color = red,
background_color = light_gray),
xtics = {["Low",1],["Medium",2],["High",3]}) $
Dibuja un histograma a partir de una muestra continua. Los datos muestrales deben darse en forma de lista de números o como una matriz unidimensional.
Opciones dispponibles:
10): número de clases del histograma, o
una lista indicando los límites de las clases y su número,
o solamente los límites.
absolute): indica la escala de las ordenadas.
Valores admitidos son: absolute, relative, percent y density.
Con density, el histograma adquiere un área total igual a uno.
auto): formato para las marcas sobre el
eje de las abscisas. Valores admitidos son: auto, endpoints,
intervals o una lista de etiquetas.
draw, excepto xrange, yrange
y xtics, que son asignadas internamente por histogram.
Si es necesario que el usuario le dé sus propios valores a estas opciones,
debe hacer uso de histogram_description. Véase el ejemplo más abajo.
draw: key, color,
fill_color, fill_density y line_width. Véase también
bars.
La función histogram_description crea un objeto gráfico
útil para formar escenas complejas, junto con otros objetos gráficos.
Se dispone también de la función wxhistogram para crear
histogramas incorporados en los interfaces wxMaxima y iMaxima.
Ejemplos:
Un histograma con seis clases:
(%i1) load ("descriptive")$
(%i2) s1 : read_list (file_search ("pidigits.data"))$
(%i3) histogram (
s1,
nclasses = 8,
title = "pi digits",
xlabel = "digits",
ylabel = "Absolute frequency",
fill_color = grey,
fill_density = 0.6)$
Ajustando los límites del histograma a -2 y 12, con 3 clases. También se establece un formato predefinido a las marcas del eje de abscisas:
(%i1) load ("descriptive")$
(%i2) s1 : read_list (file_search ("pidigits.data"))$
(%i3) histogram (
s1,
nclasses = [-2,12,3],
htics = ["A", "B", "C"],
terminal = png,
fill_color = "#23afa0",
fill_density = 0.6)$
Se hace uso de histogram_description para ajustar
la opción xrange y añadir una curva
explícita a la escena:
(%i1) load ("descriptive")$
(%i2) ( load("distrib"),
m: 14, s: 2,
s2: random_normal(m, s, 1000) ) $
(%i3) draw2d(
grid = true,
xrange = [5, 25],
histogram_description(
s2,
nclasses = 9,
frequency = density,
fill_density = 0.5),
explicit(pdf_normal(x,m,s), x, m - 3*s, m + 3* s))$
Similar a barsplot, pero dibuja sectores en lugar de rectángulos.
Opciones disponibles:
[]): una lista de colores para los
sectores. Cuando el número de sectores sea mayor que el de colores especificados,
los colores adicionales necesarios se seleccionan aleatoriamente. Véase color para más
información.
[0,0]): centro del diagrama
1): radio del diagrama.
draw, excepto key, que se asigna
internamente por piechart. Si es necesario que el usuario le dé su propio
valor a esta opción, o quiere construir una escena más compleja,
debe hacer uso de piechart_description.
draw: key, color,
fill_density y line_width. Véase también
bars.
La función piechart_description crea un objeto gráfico
útil para formar escenas complejas, junto con otros objetos gráficos.
Se dispone también de la función wxpiechart para crear
histogramas incorporados en los interfaces wxMaxima y iMaxima.
Ejemplo:
(%i1) load ("descriptive")$
(%i2) s1 : read_list (file_search ("pidigits.data"))$
(%i3) piechart(
s1,
xrange = [-1.1, 1.3],
yrange = [-1.1, 1.1],
title = "Digit frequencies in pi")$
Véase también la función barsplot.
Dibuja diagramas de dispersión, tanto de muestras univariantes (list) como multivariantes (matrix).
Las opciones disponibles son las mismas que admite histogram.
La función scatterplot_description crea un objeto gráfico
útil para formar escenas complejas, junto con otros objetos gráficos.
Se dispone también de la función wxscatterplot para crear
histogramas incorporados en los interfaces wxMaxima y iMaxima.
Ejemplos:
Diagrama de dispersión univariante a partir de una muestra normal simulada.
(%i1) load ("descriptive")$
(%i2) load ("distrib")$
(%i3) scatterplot(
random_normal(0,1,200),
xaxis = true,
point_size = 2,
dimensions = [600,150])$
Diagrama de dispersión bidimensional.
(%i1) load ("descriptive")$
(%i2) s2 : read_matrix (file_search ("wind.data"))$
(%i3) scatterplot(
submatrix(s2, 1,2,3),
title = "Data from stations #4 and #5",
point_type = diamant,
point_size = 2,
color = blue)$
Diagrama de dispersión tridimensional.
(%i1) load ("descriptive")$
(%i2) s2 : read_matrix (file_search ("wind.data"))$
(%i3) scatterplot(submatrix (s2, 1,2), nclasses=4)$
Diagrama de dispersión de cinco dimensiones, con histogramas de cinco classes.
(%i1) load ("descriptive")$
(%i2) s2 : read_matrix (file_search ("wind.data"))$
(%i3) scatterplot(
s2,
nclasses = 5,
frequency = relative,
fill_color = blue,
fill_density = 0.3,
xtics = 5)$
Para dibujar puntos aislados o unidos por segmentos, tanto en dos
como en tres dimensiones, véase points.
Véase también histogram.
Dibuja diagramas de estrellas para variables estadísticas discretas, tanto para una como para más muestras.
data puede ser una lista de resultados provenientes de una muestra o una matriz de m filas y n columnas, representando n muestras de tamaño m cada una.
Las opciones disponibles son:
[]): una lista de colores para muestras
múltiples. Cuando haya más muestras que colores especificados, los colores que faltan
se eligen aleatoriamente. Véase color para más información.
absolute): indica la escala de los radios.
Valores admitidos son: absolute y relative.
orderlessp): los valores admitidos para esta
opción son: orderlessp y ordergreatp, indicando cómo se deben ordenar
los resultados muestrales sobre el eje-x.
[]): es una lista de cadenas de
texto a usar como leyendas. Cuando la lista tenga una longitud diferente de cero o
del número de muestras, se devolverá un mensaje de error.
[0,0]): centro del diagrama.
1): radio del diagrama.
draw, excepto points_joined, point_type,
and key, que se asignan internamente por starplot. Si es necesario que el
usuario les dé sus propios valores a estas opciones, o quiere construir una escena más compleja,
debe hacer uso de starplot_description.
draw: line_width.
La función starplot_description crea un objeto gráfico
útil para formar escenas complejas, junto con otros objetos gráficos.
Se dispone también de la función wxstarplot para crear
histogramas incorporados en los interfaces wxMaxima y iMaxima.
Ejemplo:
Gráfico basado en frecuencias absolutas. La localización y el radios lo define el usuario.
(%i1) load ("descriptive")$
(%i2) l1: makelist(random(10),k,1,50)$
(%i3) l2: makelist(random(10),k,1,200)$
(%i4) starplot(
l1, l2,
stars_colors = [blue,red],
sample_keys = ["1st sample", "2nd sample"],
star_center = [1,2],
star_radius = 4,
proportional_axes = xy,
line_width = 2 ) $
Dibuja diagrama de tallos y hojas.
La única opción disponible es:
1): indica la unidad de las hojas; debe ser
una potencia de 10.
Ejemplo:
(%i1) load ("descriptive")$
(%i2) load("distrib")$
(%i3) stemplot(
random_normal(15, 6, 100),
leaf_unit = 0.1);
-5|4
0|37
1|7
3|6
4|4
5|4
6|57
7|0149
8|3
9|1334588
10|07888
11|01144467789
12|12566889
13|24778
14|047
15|223458
16|4
17|11557
18|000247
19|4467799
20|00
21|1
22|2335
23|01457
24|12356
25|455
27|79
key: 6|3 = 6.3
(%o3) done
Previous: Funciones y variables de parámetros descriptivos, Subir: descriptive [Índice general][Índice]